Paying 1k for Cad F-Key Macro

macros macros macros

Moderators: Phineas, noivad

Post Reply
User avatar
meph
Maximum Rankage
Posts: 596
Joined: Wed Apr 14, 2004 2:14 pm
Location: santa cruz, ca
Contact:

Paying 1k for Cad F-Key Macro

Post by meph » Thu Jul 14, 2011 12:07 am

I tried an F-key macro on both my Mac and PC and neither worked. If someone can write me a F-key cad macro, or even copy/paste one that will work on Windows 7 and OS 10.5 with these specifications *on top* of what an ordinary F-key cad macro should have, I will pay you 1k.

-Ability to add people to a list, numbering F1-F12.
-Have a key or mouse-control that brings up that list in my sidebar.
-Shift-click OR a mouse button (preferably mouse3, 4, or 5) to equip moonstone and self heal.
-Is NOT exile-specific in who its designed for. (i.e. if I put it in my 'Default', it'd work on all healers I have.)
-Can not use right-click for anything

It has to work on both platforms. If that means its two separate macros, that's fine. If it doesn't work, no money.

If it has other awesome bonus features, I'll pay you extra. :D
"I don't do drugs. I am drugs." - Salvador Dali

User avatar
Talas
Exile
Posts: 599
Joined: Sun Aug 22, 2010 10:57 am
Profession: Fighter
Race: Concealed
Player Status: Active
Location: Munich, Germany
Contact:

Re: Paying 1k for Cad F-Key Macro

Post by Talas » Thu Jul 14, 2011 12:51 am

meph wrote:I tried an F-key macro on both my Mac and PC and neither worked. If someone can write me a F-key cad macro, or even copy/paste one that will work on Windows 7 and OS 10.5 with these specifications *on top* of what an ordinary F-key cad macro should have, I will pay you 1k.
1k is pretty quickly earned compared to this work ;)
meph wrote:-Ability to add people to a list, numbering F1-F12.
I've seen such a macro - but didn't try it. Shouldn't be a problem...
meph wrote:-Have a key or mouse-control that brings up that list in my sidebar.
What do you mean with "sidebar" some out-of-the-game-adons to your OS? I'm pretty sure that won't work...
The maximum I could imagine is a list in your logfile which could be repeated over and over again...
meph wrote:-Shift-click OR a mouse button (preferably mouse3, 4, or 5) to equip moonstone and self heal.
shouldn't be a problem but probably needs an extra-macro. Also the other function with the F-keys are technically several macros - but maybe all in one text-file...
meph wrote:-Is NOT exile-specific in who its designed for. (i.e. if I put it in my 'Default', it'd work on all healers I have.)
That's most likely the question where you put the macro and if you overwrite the functions with other macros afterwards...
meph wrote:It has to work on both platforms. If that means its two separate macros, that's fine. If it doesn't work, no money.
does it really matter? I think the macro language does not make differences there...

User avatar
Frenzymac
Exile
Posts: 78
Joined: Thu Oct 25, 2007 3:59 am
Profession: Healer
Race: Human
Location: Austria

Re: Paying 1k for Cad F-Key Macro

Post by Frenzymac » Thu Jul 14, 2011 3:43 am

Talin posted here her store cad macro, if that helps you:
viewtopic.php?f=24&t=8361&start=0

User avatar
Onashi
Fresh off the Boat
Posts: 49
Joined: Mon May 17, 2010 10:03 pm
Profession: Ranger
Race: Ghorak Zo
Player Status: Active

Re: Paying 1k for Cad F-Key Macro

Post by Onashi » Thu Jul 14, 2011 1:31 pm

I wasn't able to get Talin's macro to work on my Windows 7 laptop, and I'll happily add another 1k for this macro

User avatar
Guinness
Exile
Posts: 331
Joined: Sun Sep 11, 2005 11:21 pm
Profession: Pied Piper
Race: Fen'neko
Player Status: Spambot

Re: Paying 1k for Cad F-Key Macro

Post by Guinness » Thu Jul 14, 2011 2:32 pm

I do like a challenge..

edit:

So you guys use..:

Moonstone: Bump heal and self heal with /use
Askeplian Staff: Ranged healing on one exile?
Caduceus: Ranged healing on many exiles?
Mercurial Staff: Burst healing, ranged? Bump?
Grank exclaims, "Oh my, a ferocious Scavenger Bird!"

Geotzou
Exile
Posts: 208
Joined: Wed May 04, 2005 9:22 am

Re: Paying 1k for Cad F-Key Macro

Post by Geotzou » Thu Jul 14, 2011 3:21 pm

Talas wrote:
meph wrote:<if you do some stuff>, I will pay you 1k.
1k is pretty quickly earned compared to this work ;)
taken as a commercial offer of [big set of 15-30 macro] <=> [1000 coins], it is simply ridiculous.

Your offer undervalues the work on macros by so much, I am much less interested to help than if nothing had been offered. (And I have spent countless hours working on crazy macros for nothing more than a thanks, this is not pure rhetoric.)

However, as Talas said it is doable, and there are a number of macro sets doing some or most of this already from the usual suspects, myself included. Good luck hypnotizing someone into seeking the privilege of being your servant...

I am not a sylphstone ring, and I will not be wrapped around your finger.

Geotzou
Devil and the deep blue sea behind me
Vanish in the air, you'll never find me
I will turn your face to alabaster
When you will find your servant is your master

User avatar
Guinness
Exile
Posts: 331
Joined: Sun Sep 11, 2005 11:21 pm
Profession: Pied Piper
Race: Fen'neko
Player Status: Spambot

Re: Paying 1k for Cad F-Key Macro

Post by Guinness » Thu Jul 14, 2011 5:49 pm

I was gonna do it for something like a Starbuck Harp. 1000c for such a macro is almost an insult for an offer.
Grank exclaims, "Oh my, a ferocious Scavenger Bird!"

User avatar
noivad
Order of the White Elephant
Order of the White Elephant
Posts: 3333
Joined: Wed Oct 08, 2003 4:04 pm
Profession: Fighter
Race: Sylvan
Player Status: Active
Location: SF Bay Area
Contact:

Re: Paying 1k for Cad F-Key Macro

Post by noivad » Thu Jul 14, 2011 6:04 pm

1K (even 2K) is far too low for all the specifications, especially the dual platform work (to test the person writing it would have to have both platforms). I'm not offering to do it for more, I'm just saying you'd be shortchanging the macro writer at that level. I'm in agreement with Geo and whomever mentioned the price. Also, the tone of the "request" is very bossy.

I suggest you examine my free moonstone_functions.txt macro for the F-key functions you want and modify it yourself, so you get exactly what you want. Also, you didn't specify what ranged healing device you use, in case someone wants to make 1K for a few hours of work.

To modify mine to ad a pull up list:
trigger
{
set x 1
set t 8
label loop
if x > 5
goto end
end if
message cadTarget[x] " as cad target F" t "."
set x + 1
set t + 1
goto loop
label end
}
http://www.clanlord.net/
Org Du Lac's bestiary: http://bestiary.clanlord.net/index.html
Gil Galad’s Pirates http://pirates.clanlord.net/ & Ranger Studies: http://studies.clanlord.net/
?security warning:View cert•CL players assess valid by refs

User avatar
Gorvin
Noble
Posts: 1001
Joined: Tue Dec 16, 2003 12:45 pm
Profession: Champion
Race: Dwarf
Player Status: Active

Re: Paying 1k for Cad F-Key Macro

Post by Gorvin » Thu Jul 14, 2011 6:09 pm

I tried an F-key macro on both my Mac and PC and neither worked
I looked into the macro Talin posted, and it doesn't work on Windows because it uses the Command key, which obviously isn't on the Windows keyboard. I've posted an edited version below that uses the Shift key in place of the Command key (so press Shift-F5 to assign the selected player to F5 for example). I also added a variable at the top of the macro so you can change the type of cad that it uses in case you don't use an Asklepain Staff. I only played around with it for a few minutes, but it seemed to be working (I use Windows 7). I don't see any reason why it wouldn't work on a Mac, but I would guess that you were probably trying to use F1-F4, which the macro doesn't use (it only uses F5 and above). The macro does almost exactly what you were asking for, barring the use of F1-F4.

As near as I can tell, the controls are:

FKEY = Cad player bound to f-key (F5-F12 ONLY)
control-FKEY = Cad player bound to control + f-key (F5-F12 ONLY)
shift-FKEY = Assign selected player to f-key (F5-F12 ONLY)
shift-control-FKEY = Assign selected player to control + f-key (F5-F12 ONLY)
shift-click = Sequentially assign clicked players to f-keys (F5-F12 ONLY)
tab = View players assigned to each f-key

(and no, I don't expect payment for this, since it isn't even my code)

Code: Select all


//store-cadding (Lena)
"cc" call simple_cad1

setglobal fkey_cad_item "asklepian staff"  // Set this to the type of cad that you use.

setglobal counter1 1

shift-click
        {
        $any_click
        "/select " @clicksplayer \r
        setglobal player @splayer
        call button
        }

        
simple_cad1
        {
        setglobal player @splayer
        call button
        }
        
        
tab call displays

                
displays
        {
        if cadtarget5 == "cadtarget5"
                message "F5:  No player selected."
        else
                "/select " cadtarget5 \r
                message "F5: "cadtarget5
                                pause 1
        end if
        
        if cadtarget6 == "cadtarget6"
                message "F6:  No player selected."
        else
                        "/select " cadtarget6 \r
                message "F6: "cadtarget6
                pause 1
        end if
        
        if cadtarget7 == "cadtarget7"
                message "F7:  No player selected."
        else
                        "/select " cadtarget7 \r
                message "F7: "cadtarget7
                pause 1
        end if
        
        if cadtarget8 == "cadtarget8"
                message "F8:  No player selected."
        else
                        "/select " cadtarget8 \r
                message "F8: "cadtarget8
                pause 1
        end if
        if cadtarget9 == "cadtarget9"
                message "F9:  No player selected."
        else
                        "/select " cadtarget9 \r
                message "F9: "cadtarget9
                pause 1
        end if
        
        if cadtarget10 == "cadtarget10"
                message "F10:  No player selected."
        else
                        "/select " cadtarget10 \r
                message "F10: "cadtarget10
                pause 1
        end if
        
        if cadtarget11 == "cadtarget11"
                message "F11:  No player selected."
        else
                        "/select " cadtarget11 \r
                message "F11: "cadtarget11
                pause 1
        end if
        
        if cadtarget12 == "cadtarget12"
                message "F12:  No player selected."
        else
                        "/select " cadtarget12 \r
                message "F12: "cadtarget12
                pause 1
        end if  
          if cadtarget13 == "cadtarget13"
                message "ctrl-f5:  No player selected."
        else
                "/select " cadtarget13 \r
                message "ctrl-f5: "cadtarget13
                                pause 1
        end if
        
        if cadtarget14 == "cadtarget14"
                message "ctrl-f6:  No player selected."
        else
                        "/select " cadtarget14 \r
                message "ctrl-f6: "cadtarget14
                pause 1
        end if
        
        if cadtarget15 == "cadtarget15"
                message "ctrl-f7:  No player selected."
        else
                        "/select " cadtarget15 \r
                message "ctrl-f7: "cadtarget15
                pause 1
        end if
        
        if cadtarget16 == "cadtarget16"
                message "ctrl-f8:  No player selected."
        else
                        "/select " cadtarget16 \r
                message "ctrl-f8: "cadtarget16
                pause 1
        end if
        if cadtarget17 == "cadtarget17"
                message "ctrl-f9:  No player selected."
        else
                        "/select " cadtarget17 \r
                message "ctrl-f9: "cadtarget17
                pause 1
        end if
        
        if cadtarget18 == "cadtarget18"
                message "ctrl-f10:  No player selected."
        else
                        "/select " cadtarget18 \r
                message "ctrl-f10: "cadtarget18
                pause 1
        end if
        
        if cadtarget19 == "cadtarget19"
                message "ctrl-f11:  No player selected."
        else
                        "/select " cadtarget19 \r
                message "ctrl-f11: "cadtarget19
                pause 1
        end if
        
        if cadtarget20 == "cadtarget20"
                message "ctrl-f12:  No player selected."
        else
                        "/select " cadtarget20 \r
                message "ctrl-f12: "cadtarget20
                pause 1
        end if  
        }
        
        


        
f5
        {

        if cadtarget5 == "cadtarget5"
                message "*No player selected"
        else
                setglobal player cadtarget5
                call button2
        end if
        }
        
f6
        {
        if cadtarget6 == "cadtarget6"
                                message "*No player selected"
        else
                setglobal player cadtarget6
                call button2
        end if
        }
        
f7
        {
        if cadtarget7 == "cadtarget7"
                                message "*No player selected"
        else
                setglobal player cadtarget7
                call button2
        end if
        }
        
f8
        {
        if cadtarget8 == "cadtarget8"
                                message "*No player selected"
        else
                setglobal player cadtarget8
                call button2
        end if
        }

f9
        {
        if cadtarget9 == "cadtarget9"
                                message "*No player selected"
        else
                setglobal player cadtarget9
                call button2
        end if
        }
        
f10
        {
        if cadtarget10 == "cadtarget10"
                                message "*No player selected"
        else
                setglobal player cadtarget10
                call button2
        end if
        }
        
f11
        {
        if cadtarget11 == "cadtarget11"
                                message "*No player selected"
        else
                setglobal player cadtarget11
                call button2
        end if
        }
        
f12
        {
        if cadtarget12 == "cadtarget12"
                                message "*No player selected"
        else
                setglobal player cadtarget12
                call button2
        end if
        }

control-f5
        {

        if cadtarget13 == "cadtarget13"
                message "*No player selected"
        else
                setglobal player cadtarget13
                call button2
        end if
        }
        
control-f6
        {
        if cadtarget14 == "cadtarget14"
                                message "*No player selected"
        else
                setglobal player cadtarget14
                call button2
        end if
        }
        
control-f7
        {
        if cadtarget15 == "cadtarget15"
                                message "*No player selected"
        else
                setglobal player cadtarget15
                call button2
        end if
        }
        
control-f8
        {
        if cadtarget16 == "cadtarget16"
                                message "*No player selected"
        else
                setglobal player cadtarget16
                call button2
        end if
        }

control-f9
        {
        if cadtarget17 == "cadtarget17"
                                message "*No player selected"
        else
                setglobal player cadtarget17
                call button2
        end if
        }
        
control-f10
        {
        if cadtarget18 == "cadtarget18"
                                message "*No player selected"
        else
                setglobal player cadtarget18
                call button2
        end if
        }
        
control-f11
        {
        if cadtarget19 == "cadtarget19"
                                message "*No player selected"
        else
                setglobal player cadtarget19
                call button2
        end if
        }
        
control-f12
        {
        if cadtarget20 == "cadtarget20"
                                message "*No player selected"
        else
                setglobal player cadtarget20
                call button2
        end if
        }


button2
        {
        set user @my.name
        if player == ""
                call selfheal
        else if player == user
                call selfheal
        else
                call cad2
        end if
                }


button
        {
        set user @my.name
        if player == ""
                call selfheal
        else if player == user
                call selfheal
        else
                call cad
        end if
                }
                
                


                

selfheal
        {
        if @my.right_item == "moonstone"
                goto done
        end if
        "/equip moonstone" \r

        label wait_for_moonstone
        if @my.right_item == "moonstone"
                goto done
        else
                pause 2
                goto wait_for_moonstone
        end if

        label done
        "/use 3" \r
        }

cad
        {
        if @my.right_item == fkey_cad_item
                goto done
        end if
        "/equip \"" fkey_cad_item "\"\r"
        label wait_for_cad
        if @my.right_item == fkey_cad_item
                goto done
        else
                pause 2
                goto wait_for_cad
        end if

        label done
        "/use " player \r
        message "*You are healing " player "."
        call rotatename
        }
        

cad2
        {
        if @my.right_item == fkey_cad_item
                goto done
        end if
        "/equip \"" fkey_cad_item "\"\r"
        label wait_for_cad
        if @my.right_item == fkey_cad_item
                goto done
        else
                pause 2
                goto wait_for_cad
        end if

        label done
        "/use " player \r
        message "*You are healing " player "."

        }
        
rotatename
        {

        if counter1 == 1
                setglobal cadtarget5 ""
                setglobal cadtarget6 "cadtarget6"
                setglobal cadtarget7 "cadtarget7"       
                setglobal cadtarget8 "cadtarget8"
                setglobal cadtarget9 "cadtarget9"
                setglobal cadtarget10 "cadtarget10"
                setglobal cadtarget11 "cadtarget11"     
                setglobal cadtarget12 "cadtarget12"             
            setglobal cadtarget13 "cadtarget13"
                setglobal cadtarget14 "cadtarget14"
                setglobal cadtarget15 "cadtarget15"       
                setglobal cadtarget16 "cadtarget16"
                setglobal cadtarget17 "cadtarget17"
                setglobal cadtarget18 "cadtarget18"
                setglobal cadtarget19 "cadtarget19"     
                setglobal cadtarget20 "cadtarget20"                                                 

                setglobal cadtarget5 @splayer

        else if counter1 == 2
                setglobal cadtarget6 @splayer
        else if counter1 == 3
                setglobal cadtarget7 @splayer
        else if counter1 == 4
                setglobal cadtarget8 @splayer           
        else if counter1 == 5
                setglobal cadtarget9 @splayer           
        else if counter1 == 6
                setglobal cadtarget10 @splayer          
        else if counter1 == 7
                setglobal cadtarget11 @splayer  
        else if counter1 == 8
                setglobal cadtarget12 @splayer 
        else if counter1 == 9
                setglobal cadtarget13 @splayer
        else if counter1 == 10
                setglobal cadtarget14 @splayer
        else if counter1 == 11
                setglobal cadtarget15 @splayer           
        else if counter1 == 12
                setglobal cadtarget16 @splayer           
        else if counter1 == 13
                setglobal cadtarget17 @splayer          
        else if counter1 == 14
                setglobal cadtarget18 @splayer  
        else if counter1 == 15
                setglobal cadtarget19 @splayer         
        else if counter1 == 16
                setglobal cadtarget20 @splayer               
                
        else
                message "*Invalid counter1" counter1
        end if
if counter1 == 16
                setglobal counter1 1

        else
                setglobal counter1 + 1
        end if
        }
//Noivad's addition

shift-F5 setglobal cadtarget5 @splayer
            
shift-F6 setglobal cadtarget6 @splayer
      
shift-F7 setglobal cadtarget7 @splayer
      
shift-F8 setglobal cadtarget8 @splayer
      
shift-F9 setglobal cadtarget9 @splayer
      
shift-F10 setglobal cadtarget10 @splayer
      
shift-F11 setglobal cadtarget11 @splayer
      
shift-F12 setglobal cadtarget12 @splayer

shift-control-f5 setglobal cadtarget13 @splayer
            
shift-control-f6 setglobal cadtarget14 @splayer
      
shift-control-f7 setglobal cadtarget15 @splayer
      
shift-control-f8 setglobal cadtarget16 @splayer
      
shift-control-f9 setglobal cadtarget17 @splayer
      
shift-control-f10 setglobal cadtarget18 @splayer
      
shift-control-f11 setglobal cadtarget19 @splayer
      
shift-control-f12 setglobal cadtarget20 @splayer

User avatar
Jeanne
Sun Dragon Clan
Sun Dragon Clan
Posts: 859
Joined: Thu Apr 10, 2003 8:18 am
Profession: Bloodmage
Race: Fen'neko
Player Status: Spambot
Location: Looking at the Moon
Contact:

Re: Paying 1k for Cad F-Key Macro

Post by Jeanne » Sat Jul 16, 2011 2:20 am

I modified Slyph's original Function key macro to add extra function keys as well as support for radius healing. I think it does everything you want it to, but since it's not originally mine I can't accept the money either.

I use this macro constantly so it definitely works. If you don't like the hotkeys for the commands or don't radius heal, that part can be removed without making the macro inoperable.

P.S. I'm not sure why people are saying you have a bossy attitude. This is the macros section. You want a macro to do specific tasks and are willing to pay money for it. What's wrong with that?

P.P.S. Gorvin said that there is no command on Windows so I changed the command to control.

Code: Select all

// Based on Slyph's Cadding Macro.

// Change these to what you use

//  Initial Healing Device
set device "asklepian"

//  Number of pulses to use at once when self-healing
set moonstone_use 3

//  Pause for Auto Self Heal routine
set moonstone_pause 30

// Help Menu
"/cadhelp"
{
message "------------------------------"
message "control click a target: heals target"
message "control click anywhere: heals self"
message "F1 - 12: heals your targets"
message "tab: heals who you were just healing"
message "esc: auto self-heal toggle"
message "F13: Radius Heal"
message "------------------------------"
message "control-option-click: sets targets 1 to 12"
message "ct name: sets targets 1 to 12"
message "Home: shows all targets"
message "End: clears all targets"
message "------------------------------"
}

//  Click button for distance healing a target.
//  Also for clicking on yourself or the ground
//  for a self-heal.
control-click
{
$any_click
if auto_selfheal == on
	setglobal auto_selfheal off
	message "*Auto Self-heal is OFF"
end if
"/select " @clicksplayer "\r"
setglobal target @selplayer.simple_name
if target == ""
	"/select\r"
	if @my.right_item != "moonstone"
		"/equip moonstone\r"
	end if
	"/use " moonstone_use "\r"
else if target == @my.simple_name
	"/select\r"
	if @my.right_item != "moonstone"
		"/equip moonstone\r"
	end if
	"/use " moonstone_use "\r"
else
	call equip-device
	setglobal cad_target target
	"/use " cad_target "\r"
	message "--------------------"
	message "*Now healing " cad_target
end if
}

//  This button begins or ends the Auto Self heal routine.
escape
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
	goto end
else
	setglobal auto_selfheal on
	message "---------------"
	message "*Auto Self-heal is ON"
end if
"/select\r"
if @my.right_item != "moonstone"
	"/equip moonstone\r"
end if
label begin
if @my.right_item == "chain"
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
	goto end
end if
if auto_selfheal == off
	message "---------------"
	message "*Auto Self-heal is OFF"
	goto end
end if
"/use " moonstone_use "\r"
pause moonstone_pause
goto begin
label end
}

//  This button will asign an exile to a preset target slot.
//  It will begin with slot 1, go as high as 12, and then
//  begin with slot 1 again.
control-option-click
{
"/select " @clicksplayer "\r"
setglobal target_num + 1
setglobal cad_lock[target_num] @selplayer.simple_name
message "--------------------"
message "*Target " target_num ": " cad_lock[target_num]
if target_num == 12
	setglobal target_num 0
end if
"/select\r"
}

//  This button will asign an exile to a preset target slot
//  with a text command, which is useful for adding
//  exiles who are not within sight of your healer.
//  It will begin with slot 1, go as high as 12, and then
//  begin with slot 1 again.
"ct"
{
"/select " @text "\r"
if @selplayer.simple_name == ""
	message "--------------------"
	message "*No such exile, or not a unique name."
	goto end
end if
setglobal target_check @selplayer.simple_name
"/select\r"
if target_check == @my.simple_name
	message "--------------------"
	message "*You cannot add youself."
	goto end
end if
setglobal target_num + 1
setglobal cad_lock[target_num] target_check
message "--------------------"
message "*Target " target_num ": " cad_lock[target_num]
if target_num == 12
	setglobal target_num 0
end if
label end
}

// This button lists the names of your 12 preset targets.
home
{
set counter 1
message "--------------------"
label top
set target_name[counter] cad_lock[counter]
if target_name[counter] == ""
	set  target_name[counter] "-----"
end if
message "*Target " counter ": " target_name[counter]
set counter + 1
if counter < 13
	goto top
end if
}

// This button clears all the names from your four preset targets.
end
{
setglobal cad_lock[1] ""
setglobal cad_lock[2] ""
setglobal cad_lock[3] ""
setglobal cad_lock[4] ""
setglobal cad_lock[5] ""
setglobal cad_lock[6] ""
setglobal cad_lock[7] ""
setglobal cad_lock[8] ""
setglobal cad_lock[9] ""
setglobal cad_lock[10] ""
setglobal cad_lock[11] ""
setglobal cad_lock[12] ""
setglobal target_num 0
message "--------------------"
message "*All Targets cleared."
}

//  This button will start distance healing Target 1.
f1
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 1
call cad-target
}

//  This button will start distance healing Target 2.
f2
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 2
call cad-target
}

//  This button will start distance healing Target 3.
f3
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 3
call cad-target
}

//  This button will start distance healing Target 4.
f4
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 4
call cad-target
}

//  This button will start distance healing Target 5.
f5
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 5
call cad-target
}

//  This button will start distance healing Target 6.
f6
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 6
call cad-target
}

//  This button will start distance healing Target 7.
f7
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 7
call cad-target
}

//  This button will start distance healing Target 8.
f8
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 8
call cad-target
}

//  This button will start distance healing Target 9.
f9
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 9
call cad-target
}

//  This button will start distance healing Target 10.
f10
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 10
call cad-target
}

//  This button will start distance healing Target 11.
f11
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 11
call cad-target
}

//  This button will start distance healing Target 12.
f12
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "---------------"
	message "*Auto Self-heal is OFF"
end if
setglobal now-cadding 12
call cad-target
}

// This button will radius heal
f13
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "*Auto Self-heal is OFF"
end if
if @my.right_item != "asklepian"
	"/equip asklepian\r"
end if
"/use\r"
}

//  Button for healing the person you were just distance healing.
//  This is useful for snell crossings, or for when you run out of
//  spirit.
tab
{
if auto_selfheal == on
	setglobal auto_selfheal off
	message "*Auto Self-heal is OFF"
end if
call equip-device
"/select " cad_target "\r"
"/use " cad_target "\r"
message "--------------------"
message "*Now healing " cad_target
}

// Variables and Sub-Routines
set target_num 0
set auto_selfheal off
set target ""
set cad_target ""
set prev_target ""
set place_holder ""
set now-cadding 0
set cad_lock[1] ""
set cad_lock[2] ""
set cad_lock[3] ""
set cad_lock[4] ""
set cad_lock[5] ""
set cad_lock[6] ""
set cad_lock[7] ""
set cad_lock[8] ""
set cad_lock[9] ""
set cad_lock[10] ""
set cad_lock[11] ""
set cad_lock[12] ""

cad-target
{
if cad_lock[now-cadding] == ""
	message "-------------------"
	message "*There is no Target " now-cadding
	"/select\r"
	goto end
end if
"/select " cad_lock[now-cadding] "\r"
call equip-device
"/use " cad_lock[now-cadding] "\r"
setglobal cad_target cad_lock[now-cadding]
label heal
message "--------------------"
message "*Now healing " cad_lock[now-cadding]
label end
}

equip-device
{
if @my.right_item != device
	"/equip " device "\r"
end if
}
Last edited by Jeanne on Tue Jul 19, 2011 8:22 am, edited 4 times in total.
Jeanne (Bloodmage) - Moon Kitty (Healer) - Himitsu (Fighter/Ranger)
Lok'Groton Adventures

Appletell - Apple, Mac, iPod, iPad, iPhone news and reviews and commentary.

Talin
Noble
Posts: 1150
Joined: Sat Apr 03, 2004 4:13 pm
Profession: Healer
Race: Sylvan
Player Status: Active
Contact:

Re: Paying 1k for Cad F-Key Macro

Post by Talin » Sat Jul 16, 2011 5:06 am

I have tykan, and other potions under f1-4, therefore I don't use them in the cad macro. Enhancing the Talin+Noi+Lena(+Gorv for Windows) macro to use more f-keys is a piece of cake. As others wrote, keep your coins, and your attitude, thank you very much.
meph wrote: -Have a key or mouse-control that brings up that list in my sidebar.
As Gorvin noted, the TNLG macro does that already with tab-key.
meph wrote: -Shift-click OR a mouse button (preferably mouse3, 4, or 5) to equip moonstone and self heal.
I use nother macro for that:
wheelup
{
if @my.right_item != "moonstone"
"/equip moonstone" \r
else
"/use" \r
end if
}

Wheeldown I use for chain, same macro. Again, works on Mac.

Post Reply